@echo off
:: This sets the variables as local, so you can use another batch file with A and B variables
setlocal ENABLEDELAYEDEXPANSION

:: determine if 32 or 64 bit run
ECHO.%PROCESSOR_ARCHITECTURE% | FIND /I "64">Nul && ( set platform=w64) || ( set platform=w32)
IF %platform% == w32 (
	goto :break
) ELSE (
	echo Running with %platform% version of TUFLOW
)

:: set executable (relative path)
set exe=..\exe\2018-03-AA\TUFLOW_iSP_%platform%.exe
echo Executable: %exe%
::
echo getting system info using  get_computer_info_%platform%.bat
call get_computer_info_%platform%.bat
echo done getting system info
pause

echo.
echo Starting High Performance HPC Solver GPU hardware simulations
set A=05.00m 02.50m
:: Loop through each cell size
FOR %%a in (%A%) do (
    echo Running %%a model with HPC GPU solver
    Start "TUFLOW" /wait %exe% -b -s1 HPC -s2 GPU -s3 PU1 -s4 %%a FMA_T2_~s1~_~s2~_~s3~_~s4~_001.tcf
)
echo Finished High Performance Benchmarking Runs
goto :end

:break
echo Unable to run benchmark tests. From release 2017-09-AA, TUFLOW no longer supports 32 bit architecture.

:end
pause

